FKits | Minecraft sunucunuz için harika kit skripti | Adakit skriptlerinizi çöpe atabilirsiniz.

Fhalinkz

Marangoz
Mesajlar
50
En iyi cevaplar
0
Beğeniler
28
Puanları
435
Merhaba Türkiye'nin sevgili Minecraft oyuncuları, bugün harika bir kit skripti ile karşınızdayım. Skriptimin adı FKits.

Melişmiş Mada Mit Mkritpi

delay kısmında yazdığınız süre saniye cinsindendir.
Skript %100 yaml kullanmaktadır.
Tek seferlik kitler için yaml'da delay kısmında herhangi sayı olmayan bir sembol bırakmanız yeterlidir.


YAML:
kits:
    adakit:
        name: "&fAda &6Kit"
        permission: fkits.kits.adakit
        delay: "-"
        lore:
        - " "
        - "&8&m----------------------"
        - " "
        - "&fElmas &6Kılıç"
        - " "
        - "&6Büyüler;"
        - "&8> &fKeskinlik: &610"
        - "&8> &fKırılmazlık: &610"
        - " "
        - "&8&m----------------------"
        - " "
        - "64x Elmas &6Spawner"
        - " "
        - "&8&m----------------------"
        - " "
        - "64x Demir &6Spawner"
        - " "
        - "&8&m----------------------"
        - " "
        - "&8>&6&nKiti almak için tıkla"
        - " "
        items:
            kilic:
                name: "&fElmas &6Kılıç"
                item: "diamond sword"
                amount: 1
                lore:
                - "Bu bir kılıç"
                - "Adakit Kılıcı"
                enchant:
                - "unbreaking 10"
                - "sharpness 10"
            spawner:
                commands:
                    console:
                        - "sp ver %player% elmas 64"
                        - "sp ver %player% demir 64"
    aletler:
        name: "&fAletler &2Kiti"
        permission: fkits.kits.aletler
        delay: 10
        lore:
        - " "
        - "&8&m----------------------"
        - " "
        - "&fDemir &2Balta"
        - " "
        - "&2Büyüler;"
        - "&8> &fVerimlilik: &210"
        - "&8> &fKırılmazlık: &210"
        - " "
        - "&8&m----------------------"
        - " "
        - "&fDemir &2Kürek"
        - " "
        - "&2Büyüler;"
        - "&8> &fVerimlilik: &210"
        - "&8> &fKırılmazlık: &210"
        - " "
        - "&8&m----------------------"
        - " "
        - "&fDemir &2Kazma"
        - " "
        - "&2Büyüler;"
        - "&8> &fVerimlilik: &210"
        - "&8> &fKırılmazlık: &210"
        - " "
        - "&8&m----------------------"
        - " "
        - "&8>&2&nKiti almak için tıkla"
        - " "
        items:
            balta:
                name: "&fDemir &2Balta"
                item: "iron axe"
                amount: 1
                lore:
                - "Aletler Baltası"
                enchant:
                - "unbreaking 10"
                - "efficiency 10"
            kazma:
                name: "&fDemir &2Kazma"
                item: "iron pickaxe"
                amount: 1
                lore:
                - "Aletler Kazması"
                enchant:
                - "unbreaking 10"
                - "efficiency 10"
            kürek:
                name: "&fDemir &2Kürek"
                item: "iron shovel"
                amount: 1
                lore:
                - "Aletler Küreği"
                enchant:
                - "unbreaking 10"
                - "efficiency 10"

Kod:
on load:
    load yaml "plugins/fKits/kits.yaml" as "kits"
    load yaml "plugins/fKits/players.yaml" as "players"

function fkityaml(p: player, t: boolean):
    if {_t} is true:
        loop yaml nodes with keys "players.%{_p}%" from "players":
            if yaml value "players.%{_p}%.%loop-value%" from "players" is less than now:
                if yaml value "players.%{_p}%.%loop-value%" from "players" isn't text:
                    delete yaml value "players.%{_p}%.%loop-value%" from "players"
    if {_t} is false:
        loop yaml nodes with keys "players.%{_p}%" from "players":
            if yaml value "players.%{_p}%.%loop-value%" from "players" is less than now:
                delete yaml value "players.%{_p}%.%loop-value%" from "players"
    save yaml "players"

every 30 minutes:
    loop yaml nodes with keys "players" from "players":
        set {_p} to "%loop-value%" parsed as offline player
        fkityaml({_p}, true)

command /fkit [<text>] [<text>] [<player>]:
    aliases: fkits
    trigger:
        if arg-1 isn't set:
            send ""
            send "&e&lMevcut kitler:" to player
            loop yaml nodes with keys "kits" from "kits":
                if player has permission yaml value "kits.%loop-value%.permission" from "kits":
                    set {_name} to yaml value "kits.%loop-value%.name" from "kits"
                    set {_lore::*} to yaml list "kits.%loop-value%.lore" from "kits"
                send "<ttp:&eKit içeriği:%nl%    %join {_lore::*} with nl%><cmd:/fkit %loop-value%>    &c> %{_name}%<reset>" to player
            send ""
        if arg-1 is "sıfırla":
            if player has permission "fkits.admin":
                if arg-3 is set:
                    delete yaml value "players.%arg-3%.%arg-2%" from "players"
                if arg-3 isn't set:
                    loop yaml nodes with keys "players" from "players":
                        set {_p} to "%loop-value%" parsed as offline player
                        fkityaml({_p}, false)
                save yaml "players"
        else if arg-1 is set:
            loop yaml nodes with keys "kits" from "kits":
                add loop-value to {_loop::*}
            if {_loop::*} contains arg-1:
                set {_permission} to yaml value "kits.%arg-1%.permission" from "kits"
                if player has permission {_permission}:
                    set {_time} to yaml value "players.%player%.%arg-1%" from "players"
                    if {_time} isn't set:
                        send "&a%arg-1% &cisimli kit başarıyla alındı."
                        fkit(player, arg-1)
                    else if {_time} is less than now:
                        send "&a%arg-1% &cisimli kit başarıyla alındı."
                        fkit(player, arg-1)
                    else:
                        send "&cBu kiti alabilmek için &a%{_time}% &ctarhini beklemelisin."
                else:
                    send "&cBu kiti alabilmek için yeterli iznin bulunmuyor."
            else:
                send "&c%arg-1% &7adında kit bulunamadı."
                execute player command "kit"
          
function fkit(p: player, t: text):
    set {_delay} to yaml value "kits.%{_t}%.delay" from "kits"
    if {_delay} is number:
        set yaml value "players.%{_p}%.%{_t}%" from "players" to ("%{_delay}% seconds" parsed as timespan) later
    else:
        set yaml value "players.%{_p}%.%{_t}%" from "players" to "-"
    save yaml "players"
    loop yaml nodes with keys "kits.%{_t}%.items" from "kits":
        set {_name} to yaml value "kits.%{_t}%.items.%loop-value%.name" from "kits"
        set {_item} to yaml value "kits.%{_t}%.items.%loop-value%.item" from "kits" parsed as itemtype
        set {_amount} to yaml value "kits.%{_t}%.items.%loop-value%.amount" from "kits"
        set {_lore::*} to yaml list "kits.%{_t}%.items.%loop-value%.lore" from "kits"
        set {_enchant::*} to yaml list "kits.%{_t}%.items.%loop-value%.enchant" from "kits"
        set {_commands::p::*} to yaml list "kits.%{_t}%.items.%loop-value%.commands.player" from "kits"
        set {_commands::c::*} to yaml list "kits.%{_t}%.items.%loop-value%.commands.console" from "kits"
        loop {_enchant::*}:
            set {_enchant::%loop-value-2%} to loop-value-2 parsed as an enchantment type
        if {_commands::p::*} is set:
            replace "%%player%%" with "%{_p}%" in {_commands::p::*}
            loop {_commands::p::*}:
                execute {_p} command loop-value-2
        if {_commands::c::*} is set:
            replace "%%player%%" with "%{_p}%" in {_commands::c::*}
            loop {_commands::c::*}:
                execute console command loop-value-2
        if {_item} is set:
            set {_item} to {_item} named "%{_name}%" with lore (join {_lore::*} with "||")
            loop {_enchant::*}:
                enchant {_item} with {_enchant::%loop-value-2%}
            give {_amount} of {_item} to {_p}
            delete {_item}

Kod:
on load:
    load yaml "plugins/fKits/kits.yaml" as "kits"
    load yaml "plugins/fKits/players.yaml" as "players"

function fkityaml(p: player, t: boolean):
    if {_t} is true:
        loop yaml nodes with keys "players.%{_p}%" from "players":
            if yaml value "players.%{_p}%.%loop-value%" from "players" is less than now:
                if yaml value "players.%{_p}%.%loop-value%" from "players" isn't text:
                    delete yaml value "players.%{_p}%.%loop-value%" from "players"
    if {_t} is false:
        loop yaml nodes with keys "players.%{_p}%" from "players":
            if yaml value "players.%{_p}%.%loop-value%" from "players" is less than now:
                delete yaml value "players.%{_p}%.%loop-value%" from "players"
    save yaml "players"

every 30 minutes:
    loop yaml nodes with keys "players" from "players":
        set {_p} to "%loop-value%" parsed as offline player
        fkityaml({_p}, true)

command /fkit [<text>] [<text>] [<player>]:
    aliases: fkits
    trigger:
        if arg-1 isn't set:
            send ""
            send "&e&lMevcut kitler:" to player
            loop yaml nodes with keys "kits" from "kits":
                if player has permission yaml value "kits.%loop-value%.permission" from "kits":
                    set {_name} to yaml value "kits.%loop-value%.name" from "kits"
                    set {_lore::*} to yaml list "kits.%loop-value%.lore" from "kits"
                send "<ttp:&eKit içeriği:%nl%    %join {_lore::*} with nl%><cmd:/fkit %loop-value%>    &c> %{_name}%<reset>" to player
            send ""
        if arg-1 is "sıfırla":
            if player has permission "fkits.admin":
                if arg-3 is set:
                    delete yaml value "players.%arg-3%.%arg-2%" from "players"
                if arg-3 isn't set:
                    loop yaml nodes with keys "players" from "players":
                        set {_p} to "%loop-value%" parsed as offline player
                        fkityaml({_p}, false)
                save yaml "players"
        else if arg-1 is set:
            loop yaml nodes with keys "kits" from "kits":
                add loop-value to {_loop::*}
            if {_loop::*} contains arg-1:
                set {_permission} to yaml value "kits.%arg-1%.permission" from "kits"
                if player has permission {_permission}:
                    set {_time} to yaml value "players.%player%.%arg-1%" from "players"
                    if {_time} isn't set:
                        send "&a%arg-1% &cisimli kit başarıyla alındı."
                        fkit(player, arg-1)
                    else if {_time} is less than now:
                        send "&a%arg-1% &cisimli kit başarıyla alındı."
                        fkit(player, arg-1)
                    else:
                        send "&cBu kiti alabilmek için &a%{_time}% &ctarhini beklemelisin."
                else:
                    send "&cBu kiti alabilmek için yeterli iznin bulunmuyor."
            else:
                send "&c%arg-1% &7adında kit bulunamadı."
                execute player command "kit"
           
function fkit(p: player, t: text):
    set {_delay} to yaml value "kits.%{_t}%.delay" from "kits"
    if {_delay} is number:
        set yaml value "players.%{_p}%.%{_t}%" from "players" to ("%{_delay}% seconds" parsed as timespan) later
    else:
        set yaml value "players.%{_p}%.%{_t}%" from "players" to "-"
    save yaml "players"
    loop yaml nodes with keys "kits.%{_t}%.items" from "kits":
        set {_s::name} to yaml value "kits.%{_t}%.items.%loop-value%.name" from "kits"
        set {_s::item} to yaml value "kits.%{_t}%.items.%loop-value%.item" from "kits" parsed as itemtype
        set {_s::amount} to yaml value "kits.%{_t}%.items.%loop-value%.amount" from "kits"
        set {_s::lore::*} to yaml list "kits.%{_t}%.items.%loop-value%.lore" from "kits"
        set {_s::enchant::*} to yaml list "kits.%{_t}%.items.%loop-value%.enchant" from "kits"
        set {_s::commands::p::*} to yaml list "kits.%{_t}%.items.%loop-value%.commands.player" from "kits"
        set {_s::commands::c::*} to yaml list "kits.%{_t}%.items.%loop-value%.commands.console" from "kits"
        loop {_s::enchant::*}:
            set {_s::enchant::%loop-value-2%} to loop-value-2 parsed as an enchantment type
        if {_s::commands::p::*} is set:
            replace "%%player%%" with "%{_p}%" in {_s::commands::p::*}
            loop {_s::commands::p::*}:
                execute {_p} command loop-value-2
        if {_s::commands::c::*} is set:
            replace "%%player%%" with "%{_p}%" in {_s::commands::c::*}
            loop {_s::commands::c::*}:
                execute console command loop-value-2
        if {_s::item} is set:
            set {_s::item} to {_s::item} named "%{_s::name}%" with lore (join {_s::lore::*} with "||")
            loop {_s::enchant::*}:
                enchant {_s::item} with {_s::enchant::%loop-value-2%}
            give {_s::amount} of {_s::item} to {_p}
            delete {_s::*}

Skript paylaşıldı
Kit alırken sıradaki eşyaya yanlış şeyler gitme hatası düzeltildi.

Artık her hafta ücretsiz olarak skript paylaşımı yapmayı düşünüyorum. Sıradaki skriptimiz ne olsun istersiniz? Yorumlarda belirtmeyi unutmayın.
 


Son düzenleme:

squidbey

Ağaç Yumruklayıcı
Mesajlar
11
En iyi cevaplar
0
Beğeniler
7
Puanları
20
Gerçek bir script, tıpkı SkriptGUI ve ReportX gibi. <3
 

Linny

Taş Madencisi
Mesajlar
80
En iyi cevaplar
0
Beğeniler
8
Puanları
60
Ruh hali
Discordunu atar mısın
 

ErenSB

Elmas Madencisi
Emektar Üye
Mesajlar
834
En iyi cevaplar
26
Beğeniler
537
Puanları
1,640

DerpBoy

Kömür Madencisi
Mesajlar
130
En iyi cevaplar
0
Beğeniler
34
Puanları
215
Ruh hali
Skripte aşırı çok ilgi gelmiş şaşırdım açıkçası keşke hızlı fırın v2938 falan yapsaydın
 

Üst