İstek Skript lazım Bana

Sorusoran

Sudan Çıkmış
Mesajlar
2
En iyi cevaplar
0
Beğeniler
0
Puanları
10
Selamlar.Ben skriptlerden anlamıyorum.Lütfen bana feed,heal,afk komutlarının skriptlerini yazarmısınız.Şimdiden teşekkürler.
 


ChiaX

Team Arcenia
Emektar Üye
Mesajlar
596
En iyi cevaplar
37
Beğeniler
694
Puanları
2,620
Ruh hali
Merhabalar, feed heal ve afk için Essentials eklentisini kullanabilirsin.
 

LifeMCServer

Nether Yerlisi
Mesajlar
2,410
En iyi cevaplar
98
Beğeniler
2,461
Puanları
10,250
Ruh hali
Yukarıda dendiği gibi Essentials veya alternatif eklentiler kullanabilirsin, Skript istediğin için skriptini de bırakıyorum.

JavaScript:
# Skript 2.2-dev34+ ve SkQuery gerektirir.

# 1.8 için 2.2-dev36 kullanın, üst sürümler için 2.4.1 veya o anki son sürümü.
# https://github.com/SkriptLang/Skript/releases

function heal(p: player):
 heal {_p}

function feed(p: player):
 feed {_p}

function afk(s: player, p: player):
 if {afk::%{_p}%} is true:
  afk0({_p}, false)
  if {_s} is {_p}:
   send "&aAFK modunu başarıyla kapattın." to {_s}
  else:
   send "&e%{_p}% adlı oyuncunun AFK modunu başarıyla kapattınız." to {_s}
 else:
  afk0({_p}, true)
  if {_s} is {_p}:
   send "&aAFK modunu başarıyla açtın." to {_s}
  else:
   send "&e%{_p}% adlı oyuncunun AFK modunu başarıyla açtınız." to {_s}

function afk0(p: player, b: boolean):
 if {afk::%{_p}%} is {_b}:
  stop
 set {afk::%{_p}%} to {_b}
 if {_b} is true:
  broadcast "&e%{_p}% &cartık AFK"
 else:
  broadcast "&e%{_p}% &cartık AFK değil"

command /heal [<player>]:
 permission: skript.heal
 permission message: &cGerekli yetkiniz bulunmamakta. &7(skript.heal)

 trigger:
  if arg-1 is set:
   if player have the permission "skript.heal.everyone":
    heal(arg-1)
    send "&e%arg-1% &aadlı oyuncunun canı başarıyla dolduruldu."
   else:
    send "&cGerekli yetkiniz bulunmamakta. &7(skript.heal.everyone)"
  else if command sender is a player:
   heal(player)
   send "&aCanınız başarıyla dolduruldu."
  else:
   send "&cLütfen komutu konsoldan kullanırken canını doldurmak için bir oyuncu belirtin!"

command /feed [<player>]:
 permission: skript.feed
 permission message: &cGerekli yetkiniz bulunmamakta. &7(skript.feed)

 trigger:
  if arg-1 is set:
   if player have the permission "skript.feed.everyone":
    feed(arg-1)
    send "&e%arg-1% &aadlı oyuncunun açlığı başarıyla dolduruldu."
   else:
    send "&cGerekli yetkiniz bulunmamakta. &7(skript.feed.everyone)"
  else if command sender is a player:
   feed(player)
   send "&aAçlığınız başarıyla dolduruldu."
  else:
   send "&cLütfen komutu konsoldan kullanırken açlığını doldurmak için bir oyuncu belirtin!"
      
command /afk [<player>]:
 permission: skript.afk
 permission message: &cGerekli yetkiniz bulunmamakta. &7(skript.afk)
 
 trigger:
  if arg-1 is set:
   if player have the permission "skript.afk.everyone":
    afk(player, arg-1)
   else:
    send "&cGerekli yetkiniz bulunmamakta. &7(skript.afk.everyone)"
  else if command sender is a player:
   afk(player, player)
  else:
   send "&cLütfen komutu konsoldan kullanırken afk modunu değiştirmek için bir oyuncu belirtin!"

on any move: # SkQuery
 afk0({_p}, false)

on teleport:
 afk0({_p}, false)

on chat:
 afk0({_p}, false)
 

Üst