Hadi bir skript yazalım #2 - Komutlar , Yetkiler ve Argument

[Heisen_berg]

Hadi bir skript yazalım #1 dersine gitmek için tıklayın.

Önceki dersimizde Eventler ve Efektleri gördük. Bu dersimizde ise Komut oluşturmayı, yetkileri ayarlamayı ve argument nedir onu öğreneceğiz.

İlk önce Komut oluşturmadan başlayalım.
Bir örnek göstereyim:

command /merhaba: #/merhaba komutu
    description: Merhaba Millet #Komutun açıklaması genellikle /help yazdığınızda orda çıkan açıklamadır.
    aliases: /mrb, /mrbb #Bu ise komutun kısaltılışıdır. Yani /gamemode 1 yerine /gm 1 gibi oluyor.
    usage: /merhaba #Komutun nasıl kullanılacağını gösteren mesaj
    executable by: players #Buraya players yazdığınızda sadece oyuncular kullanabilir. Console yazdığınızda sadece konsoldan kullanılabilir. Her ikisi için burayı silin.
    permission: merhaba.kullan #Komut için gerekli yetki
    permission message: Yetkiniz yok! #Yetkisi olmayanların alacağı mesaj
    trigger: #Bunu yazmazsanız komutunuz çalışmaz
        send "Merhaba Arkadaşım"  #Bu mesajı gönderir

Yukarıdaki örnek komutu kullanan kişinin "merhaba.kullan" yetkisi varsa, "Merhaba Arkadaşım" diye bir mesaj alacak. Bunun gibi komutlar hazırlayabilirsiniz.
/? merhaba yazdığımda:

Eventlerde yetkileri kullanmak istiyorsanız:

on craft: #Craft yaparken
    if player have permission "ben.proyum": #Oyuncu "ben.proyum" yetkisine sahip ise
        send "Aferin Pro Oyuncu bir esya craftladin"  #Oyuncuya mesaj gönder

Şimdi sıra argument nedir ne işe yarar komutlarda ki etkisini göreceğiz.
Örnek bir komut:

command /oldur <player>:
    permission: oldurme.yetki
    aliases: /kill
    trigger:
        kill the player-argument

Yukarıda örnekte bir argument kullanmış olduk. Bu argument <player> idi. Çok farklı argumentler var. Mesela <items> argumenti mevcut.
Bu sefer <text> argumentini kullanarak broadcast yapalım.

options:
    p: &e[Admin Diyorki:] &c

command /milletemesaj <text>:
    permission: milletemesaj.izin
    trigger:
        broadcast "{@p} %arg 1%"

Yukarıdaki kodda gördüğünüz gibi <text> argumenti text-argument olarak yazabilsek de arg 1 olarak daha kısa yazabilirsiniz. Ayrıca broadcast/text ve mesajla ilgili diğer şeylerde argument veya variables'i yüzdeneler içine almanız gerekmektedir. %arg 1% gibi...

Evet biraz şaşırmış olabilirsiniz. En üstteki "options:" nedir diye soruyor olabilirsiniz. Oradaki options sayesinde uzun kelimeleri kısa kelimeye dönüştürebiliyoruz.
Options kısmına:
p: UZUUUUUUUUUUN MESAJ
Komut/event veya text kısmına:
{@p}

Bu dersimizde komut yapmayı eventler ve komutlar için yetkiler ayarlamayı ve argumenti kullanmayı öğrendik.

 

[EymenBeyz]

Gerçekten çok güzel bir anlatım olmuş tebrik ederim.