[İstek] Lotto

[Mertka]

Selam forum üyesi bana bu skripti yazabilirmisin?
Skriptte /lotto-yap komutu ile lotto duyurusu çıkacak duyuru şu şekilde olacak "&2[&6LOTTO&2]&6: &4Lottoya katılmak icin sayi girin &a/lotto-sayi <sayi> &7[1-90]"
şeklinde lotto'da sayiyi sistem belirleyecek eğer belirleme işi zorsa yönetici belirlesin ör: /lotto-sayisi <sayi> şeklinde
puanı tutturana 17k verecek.
Not: Benim fazla skript ile aram iyi değil öğrenmeye çalışıyorum eventler vs.

 

[Won5]

Lotto derken..?
(Loto olmasın...)

 

[iZeckGH]

Lotto Marka Değilmiydi Ya

 

[Rosenrot]

rastgele sayı hangi sayılar arasında olucak yani şöyle bir şey olcak

set {sansli.sayi} to random integer between 1 and 60

bu kod 1 ve 60 arasinda rastgele bir sayi olusturur
ona göre söyle yapmaya baslayayım

 

[LegendWH]

Herhangi bir sayı getirmeyi bilseydim yaptırmakta tutturamayan para gitsin pcde değilim pcye geçince yaparim

 

[Axel102]

options:
  interval : 60 #In minutes.
  waiting : 30 #In seconds.
  ticketprice : 10
  maxnumber : 80
  minprize : 1000
  maxprize : 10000

on skript load:
  set {lotto.enabled} to false

on connect:
  {lotto.enabled} is false
  {lotto.number.%player%} is set:
    delete {lotto.number.%player%}

command /lotto [<integer>]:
  permission: skript.lotto
  trigger:
    if {lotto.enabled} is false:
      message "&cNo active lottery today."
    else if {lotto.number.%player%} is set:
      message "&cYou already bought a lottery with number &a%{lotto.number.%player%}%"
    else if argument is not set:
      message "&cUsage: /lotto <1-{@maxnumber}>"
    else if argument is smaller than 1:
      message "&cNumber cannot less than 1."
    else if argument is bigger than {@maxnumber}:
      message "&cNumber cannot exceed than {@maxnumber}."
    else if player's money is smaller than {@ticketprice}:
      message "&cNot enough money."
    else:
      remove {@ticketprice} from player's money
      message "&cYou has bought a lottery with number &a%argument% &cfor {@ticketprice}"
      set {lotto.number.%player%} to argument

every {@interval} minutes:
  execute console command "lottonow"

command /lottonow:
  permission: skript.lottonow
  trigger:
    if {lotto.enabled} is true:
      stop
    set {lotto.enabled} to true
    set {_lottowin} to false
    set {_lottonumber} to random integer from 1 to {@maxnumber}
    set {_lottoprize} to random integer from {@minprize} to {@maxprize}
    broadcast "&aLOTTERY: &bUse &6/lotto <1-{@maxnumber}> &bto buy a number! &c(Cost {@ticketprice})"
    broadcast "&6Prize: &a%{_lottoprize}%"
    wait {@waiting} seconds
    broadcast "&aLOTTERY: &bThe number is &c%{_lottonumber}%!"
    loop all players:
      if {lotto.number.%loop-player%} is {_lottonumber}:
        add loop-player to {_lottery.winner::*}
        add {_lottoprize} to loop-player's money
        set {_lottowin} to true
      delete {lotto.number.%loop-player%}
    if {_lottowin} is true:
      message "&a%{_lottery.winner::*}% &cwon the lottery!"
    if {_lottowin} is false:
      broadcast "&cNobody won the lottery!"
    set {lotto.enabled} to false

 

[Axel102]

"

Linki görebilmek için üye olmanız gerekiyor. Giriş yap veya üye ol.

" Ahahaha ^.^

?