Kıt goruntuleme skript |Kıt preview

[Sorcha0747]

Bu skript alıntıntıdır bu skript sayesinden deluxemenu,chestcommands vb pluginlerle kit görüntüleme menusu
oluşturmaktan kurtuluyoruz

/easykit create oyuncu - ilk önce görüntülemek istediğiniz kiti envantererinize ayarlıyorsunuz sonra komudu yazıyorsunuz

/easykit preview oyuncu - yazdığınızda kaydettiğiniz kiti görüntüleyebilirsiniz

gelelim obür komutlara
/easykit delete oyuncu - oluşturduğunuz kiti siler
/easykit list - oluşturduğunuz kitlerin listesini gösterir

- easykit.main
bu yetkiyi oyunculara verdiğinizde oyuncular bütün komutları kullanabilicektir forumda olan skripter arkadaşlarımız oyuncular
için /easykit preview komudu için tek permisions eklerseler çok güzel olur
Benden bukadar işinize yaradıysa ne mutlu bana

#options
options:
    prefix: &8[&9EasyKit&8] &7
    noperm: &cYou don't have permission to use this!
    version: 1.1
    info: &7Made by DieHollander.%nl%&7Version: 1.1.

function ekPreviewKit(p:player,k:text):
    open chest with 6 rows named "&8Kit: &l%{_k}%" to {_p}
    set {menu.%{_p}%} to "ekKitPreview"
    loop {easykit::kit::%{_k}%::slot::*}:
        set {_slot} to loop-index parsed as integer
        set slot {_slot} of {_p}'s current inventory to loop-value
    set slot 45 of {_p}'s current inventory to {easykit::kit::%{_k}%::helmet}
    set slot 46 of {_p}'s current inventory to {easykit::kit::%{_k}%::chestplate}
    set slot 47 of {_p}'s current inventory to {easykit::kit::%{_k}%::leggings}
    set slot 48 of {_p}'s current inventory to {easykit::kit::%{_k}%::boots}
    set {_slot} to 36
    loop 9 times:
        set slot {_slot} of {_p}'s current inventory to light blue glass pane named " "
        add 1 to {_slot}

function ekDeleteKit(p:player,k:text):
    delete {easykit::kit::%{_k}%::*}
    delete {easykit::kit::%{_k}%}

function ekCreateKit(p:player,k:text):
    ekDeleteKit({_p},{_k})
    set {_slot} to 0
    loop 36 times:
        if slot {_slot} of {_p}'s inventory is not air:
            set {easykit::kit::%{_k}%::slot::%{_slot}%} to slot {_slot} of {_p}'s inventory
        add 1 to {_slot}
    if {_p}'s helmet is set:
        set {easykit::kit::%{_k}%::helmet} to {_p}'s helmet
    if {_p}'s chestplate is set:
        set {easykit::kit::%{_k}%::chestplate} to {_p}'s chestplate
    if {_p}'s leggings is set:
        set {easykit::kit::%{_k}%::leggings} to {_p}'s leggings
    if {_p}'s boots is set:
        set {easykit::kit::%{_k}%::boots} to {_p}'s boots
    set {easykit::kit::%{_k}%} to {_k}
       
function ekGiveKit(p:player,k:text):
    clear {_p}'s inventory
    loop {easykit::kit::%{_k}%::slot::*}:
        set {_slot} to loop-index parsed as integer
        set slot {_slot} of {_p}'s inventory to loop-value
    set {_p}'s helmet to {easykit::kit::%{_k}%::helmet}
    set {_p}'s chestplate to {easykit::kit::%{_k}%::chestplate}
    set {_p}'s leggings to {easykit::kit::%{_k}%::leggings}
    set {_p}'s boots to {easykit::kit::%{_k}%::boots}
   
   
#commands
command /easykit [<text>] [<text>] [<text>] [<text>]:
    usage: /easykit
    aliases: /ek
    trigger:
        set {_use} to "{@prefix}Use '/easykit help'."
        if player has permission "easykit.main":
            if arg-1 is not set:
                message {_use}
                stop
            if arg-1 is "help":
                message "{@prefix}Help page:"
                message "&7/easykit create <kit> &8- &7Create a kit."
                message "&7/easykit delete <kit> &8- &7Delete a kit."
                message "&7/easykit preview <kit> &8- &7Preview a kit."
                message "&7/easykit list &8- &7List of kits."
                message "&7/easykit info &8- &7Script info."
                stop
            if arg-1 is "create":
                set {_use} to "{@prefix}Use '/easykit create <kit>'."
                if arg-2 is not set:
                    message {_use}
                else:
                    set {_arg2} to uncolored arg-2
                    ekCreateKit(player,{_arg2})
                    message "{@prefix}Kit %{_arg2}% created."
                stop
            if arg-1 is "delete":
                set {_use} to "{@prefix}Use '/easykit delete <kit>'."
                if arg-2 is not set:
                    message {_use}
                else:
                    set {_arg2} to uncolored arg-2
                    if {easykit::kit::%{_arg2}%} is not set:
                        message "{@prefix}This kit doesn't exist!"
                    else:
                        ekDeleteKit(player,{_arg2})
                        message "{@prefix}Kit %{_arg2}% deleted."
                stop
            if arg-1 is "preview":
                set {_use} to "{@prefix}Use '/easykit preview <kit>'."
                if arg-2 is not set:
                    message {_use}
                else:
                    set {_arg2} to uncolored arg-2
                    if {easykit::kit::%{_arg2}%} is not set:
                        message "{@prefix}This kit doesn't exist!"
                    else:
                        ekPreviewKit(player,{_arg2})
                stop
            if arg-1 is "list":
                if {easykit::kit::*} is not set:
                    message "{@prefix}There are currently no kits!"
                else:
                    message "{@prefix}All kits: %{easykit::kit::*}%."
                stop
            if arg-1 is "get":
                set {_use} to "{@prefix}Use '/easykit get <kit>'."
                if arg-2 is not set:
                    message {_use}
                else:
                    set {_arg2} to uncolored arg-2
                    if {easykit::kit::%{_arg2}%} is not set:
                        message "{@prefix}This kit doesn't exist!"
                    else:
                        ekGiveKit(player,{_arg2})
                        message "{@prefix}Received the kit %{_arg2}%."
                stop
            if arg-1 is  "give":
                set {_use} to "{@prefix}Use '/easykit give <player> <kit>'."
                if arg-2 is not set:
                    message {_use}
                else:
                    if arg-3 is not set:
                        message {_use}
                    else:
                        set {_arg2} to arg-2 parsed as offline player
                        set {_arg3} to uncolored arg-3
                        if {_arg2} is not set:
                            message "{@prefix}Player not found."
                        else:
                            if {_arg2} is not online:
                                message "{@prefix}This player is not online."
                            else:
                                if {easykit::kit::%{_arg3}%} is not set:
                                    message "{@prefix}This kit doesn't exist!"
                                else:
                                    ekGiveKit({_arg2},{_arg3})
                                    message "{@prefix}%{_arg2}% received the kit %{_arg3}%."
                stop
            if arg-1 is "info" or "version":
                message "{@prefix}{@info}"
                set {_curver} to text from "https://pastebin.com/raw/K8R02V9V"
                if {_curver} is not "{@version}":
                    message "{@prefix}New version available!"
                    make console execute command "tellraw %player% ["""",{""text"":""Download "",""color"":""gray""},{""text"":""HERE"",""bold"":true,""underlined"":true,""color"":""gray"",""clickEvent"":{""action"":""open_url"",""value"":""https://forums.skunity.com/resources/easy-kit-easiest-kit-script.517/""}},{""text"":""."",""color"":""gray""}]"
                else:
                    message "&7You are currently running the latest version of EasyKit!"
                stop
            message {_use}
        else:
            if arg-1 is not "info" or "version":
                message "{@noperm}"
            else:
                message "{@prefix}{@info}"
       
       
       
       
       

#events
on inventory click:
    if {menu.%player%} is "ekKitPreview":
        cancel event
on inventory close:
    if {menu.%player%} is set:
        delete {menu.%player%}

Gereken addonlar
- SkQuery
- Tuske

 

[Nxymn]

Yararlı ve açıklayıcı bir konu olmuş elinize sağlık.